107 lines
3.3 KiB
CMake
107 lines
3.3 KiB
CMake
|
# Extracting the subdirectories from a given folder
|
||
|
|
#
|
||
|
|
# Usage:
|
||
|
|
# SUBDIRLIST( SUBDIRS "path/to/base/dir" )
|
||
|
|
#
|
||
|
|
# Source: http://stackoverflow.com/questions/7787823/cmake-how-to-get-the-name-of-all-subdirectories-of-a-directory
|
||
|
|
|
||
|
|
MACRO(SUBDIRLIST result curdir)
|
||
|
|
FILE(GLOB children RELATIVE ${curdir} ${curdir}/*)
|
||
|
|
SET(dirlist "")
|
||
|
|
FOREACH(child ${children})
|
||
|
|
IF(IS_DIRECTORY ${curdir}/${child})
|
||
|
|
SET(dirlist ${dirlist} ${child})
|
||
|
|
ENDIF()
|
||
|
|
ENDFOREACH()
|
||
|
|
SET(${result} ${dirlist})
|
||
|
|
ENDMACRO()
|
||
|
|
|
||
|
|
# Search packages for host system instead of packages for target system
|
||
|
|
# in case of cross compilation thess macro should be defined by toolchain file
|
||
|
|
# adopted from OpenCV
|
||
|
|
if(NOT COMMAND find_host_package)
|
||
|
|
macro(find_host_package)
|
||
|
|
find_package(${ARGN})
|
||
|
|
endmacro()
|
||
|
|
endif()
|
||
|
|
if(NOT COMMAND find_host_program)
|
||
|
|
macro(find_host_program)
|
||
|
|
find_program(${ARGN})
|
||
|
|
endmacro()
|
||
|
|
endif()
|
||
|
|
|
||
|
|
macro(check_environment_variables)
|
||
|
|
foreach(_var ${ARGN})
|
||
|
|
if(NOT DEFINED ${_var} AND DEFINED ENV{${_var}})
|
||
|
|
set(__value "$ENV{${_var}}")
|
||
|
|
file(TO_CMAKE_PATH "${__value}" __value) # Assume that we receive paths
|
||
|
|
set(${_var} "${__value}")
|
||
|
|
message(STATUS "Update variable ${_var} from environment: ${${_var}}")
|
||
|
|
endif()
|
||
|
|
endforeach()
|
||
|
|
endmacro()
|
||
|
|
|
||
|
|
# Status convinience function.
|
||
|
|
# adopted from OpenCV
|
||
|
|
function(output_status msg)
|
||
|
|
message(STATUS "${msg}")
|
||
|
|
string(REPLACE "\\" "\\\\" msg "${msg}")
|
||
|
|
string(REPLACE "\"" "\\\"" msg "${msg}")
|
||
|
|
endfunction()
|
||
|
|
|
||
|
|
# Status report function.
|
||
|
|
# Automatically align right column and selects text based on condition.
|
||
|
|
# Usage:
|
||
|
|
# status(<text>)
|
||
|
|
# status(<heading> <value1> [<value2> ...])
|
||
|
|
# status(<heading> <condition> THEN <text for TRUE> ELSE <text for FALSE> )
|
||
|
|
# adopted from OpenCV
|
||
|
|
function(status text)
|
||
|
|
set(status_cond)
|
||
|
|
set(status_then)
|
||
|
|
set(status_else)
|
||
|
|
|
||
|
|
set(status_current_name "cond")
|
||
|
|
foreach(arg ${ARGN})
|
||
|
|
if(arg STREQUAL "THEN")
|
||
|
|
set(status_current_name "then")
|
||
|
|
elseif(arg STREQUAL "ELSE")
|
||
|
|
set(status_current_name "else")
|
||
|
|
else()
|
||
|
|
list(APPEND status_${status_current_name} ${arg})
|
||
|
|
endif()
|
||
|
|
endforeach()
|
||
|
|
|
||
|
|
if(DEFINED status_cond)
|
||
|
|
set(status_placeholder_length 18)
|
||
|
|
string(RANDOM LENGTH ${status_placeholder_length} ALPHABET " " status_placeholder)
|
||
|
|
string(LENGTH "${text}" status_text_length)
|
||
|
|
if(status_text_length LESS status_placeholder_length)
|
||
|
|
string(SUBSTRING "${text}${status_placeholder}" 0 ${status_placeholder_length} status_text)
|
||
|
|
elseif(DEFINED status_then OR DEFINED status_else)
|
||
|
|
output_status("${text}")
|
||
|
|
set(status_text "${status_placeholder}")
|
||
|
|
else()
|
||
|
|
set(status_text "${text}")
|
||
|
|
endif()
|
||
|
|
|
||
|
|
if(DEFINED status_then OR DEFINED status_else)
|
||
|
|
if(${status_cond})
|
||
|
|
string(REPLACE ";" " " status_then "${status_then}")
|
||
|
|
string(REGEX REPLACE "^[ \t]+" "" status_then "${status_then}")
|
||
|
|
output_status("${status_text} ${status_then}")
|
||
|
|
else()
|
||
|
|
string(REPLACE ";" " " status_else "${status_else}")
|
||
|
|
string(REGEX REPLACE "^[ \t]+" "" status_else "${status_else}")
|
||
|
|
output_status("${status_text} ${status_else}")
|
||
|
|
endif()
|
||
|
|
else()
|
||
|
|
string(REPLACE ";" " " status_cond "${status_cond}")
|
||
|
|
string(REGEX REPLACE "^[ \t]+" "" status_cond "${status_cond}")
|
||
|
|
output_status("${status_text} ${status_cond}")
|
||
|
|
endif()
|
||
|
|
else()
|
||
|
|
output_status("${text}")
|
||
|
|
endif()
|
||
|
|
endfunction()
|